//Eric Brockmeyer
//Interactive Art and Computational Design 
//January 11, 2011
//Reproduction of "Schotter" by Georg Nees
//press ENTER to pause!
Square[][] squares = new Square[12][24];
int keyValue = 0;
void setup(){
  size(241, 481);
  frameRate(24);
  background(#000000);
  for (int i = 0; i < 12; i++){
   for (int j = 0; j < 24; j++){
    squares[i][j] = new Square(i,j);
   }    
  }
}
void draw(){
  background(#000000);
  drawSquares();
}
void drawSquares(){
  for (int i = 0; i < 12; i++){
   for (int j = 0; j < 24; j++){
    squares[i][j].move();
    squares[i][j].draw();
   }    
  }
}
void keyPressed(){
  if (key == ENTER){
   if (keyValue == 0){
    keyValue = 1;
    noLoop();
   } 
   else {
    keyValue = 0; 
    loop();
   }  
  } 
}
class Square {
  int x, y, dim;
  float rotation;
  float xRandom, yRandom;
  Square(int xTemp, int yTemp) {
    x = xTemp;
    y = yTemp;
    dim = 20;
    rotation = 0;
  }
  void move() {
    rotation = y * random(0.05);
    xRandom = x + Y * random(-0.05,0.05);
    yRandom = y + y * random(-0.05,0.05);
  }
  void draw() {
    pushMatrix(); 
    translate(xRandom*dim+(dim/2), yRandom*dim+(dim/2)); 
    rotate(rotation);
    translate(-dim/2, -dim/2);
    noFill();
    strokeWeight(1);
    stroke(#ffffff);
    rect(0, 0, dim, dim);
    popMatrix(); 
  }
}